Microsoft Windows – Script para instalação via GPO

Este guia fornece um procedimento passo a passo para implantar o Desktop Agent e Agent Server Agent em ambientes Microsoft Windows utilizando Objetos de Política de Grupo (GPO) com um script de inicialização. Esse método permite a instalação centralizada, automatizada e silenciosa em vários dispositivos em um ambiente de domínio.

Antes de começar, certifique-se de que:

• O pacote de instalação (.exe) está disponível através de um compartilhamento de rede (caminho UNC)
• Ambiente de domínio com o Active Directory configurado
• Privilégios administrativos para criar e editar GPOs
• Os computadores de destino estão associados ao domínio

1. Coloque o instalador em uma pasta compartilhada: \\servidor\pasta\AgentInstaller.exe
2. Certifique-se de:
   • Permissão de leitura para computadores do domínio
   • O caminho de rede está acessível a partir das máquinas de destino

Criar um .bat arquivo (por exemplo, install_agent.bat) e utilize o script abaixo.

@echo off

::##################################################
::############### GPO Agent Almaden ###############
::##################################################

REM ATTENTION!
REM MODIFY LINE 12 ApplicationPath WITH THE PACKAGE PATH
REM MODIFY LINE 19 ExpectedValue WITH THE VERSION TO BE INSTALLED

REM Local or network path of the application to be installed
set "ApplicationPath=\\servidor\pasta\Nome_Do_Pacote.exe"

REM Registry path where the DisplayVersion value is stored
set "RegistryKey=HKLM\SOFTWARE\WOW6432Node\Microsoft\Windows\CurrentVersion\Uninstall\{F5B62352-F120-4D57-815C-FB240F6000FC}"
set "ValueName=DisplayVersion"

REM Agent version
set "ExpectedValue=4.4.0"
set "CurrentValue="

REM Check if the registry key exists
reg query "%RegistryKey%" >nul 2>&1
if %errorlevel% equ 0 (
    REM Attempt to read the DisplayVersion value
    for /f "tokens=3*" %%a in ('reg query "%RegistryKey%" /v %ValueName% 2^>nul ^| findstr /i %ValueName%') do (
        set "CurrentValue=%%a"
    )
)

REM Compare with expected value
if /i "%CurrentValue%"=="%ExpectedValue%" goto VersionFound
goto Install

:VersionFound
echo Current version already installed, exiting script
goto End

:Install
echo Installing new version...
start "" "%ApplicationPath%"
echo Installation completed.

:End
exit /b

Antes de utilizar o script em produção, é obrigatório ajustar duas linhas específicas. Esses parâmetros definem onde o instalador está localizado e qual versão deve ser considerada válida.

Exemplo

defina "ApplicationPath=\\fileserver\software\AlmadenAgent.exe"

Considerações importantes

• Deve ser um caminho de rede (UNC), não um caminho local
• Os computadores de destino devem ter permissão de leitura
• O arquivo deve estar acessível durante a inicialização do sistema (execução do GPO)

Exemplo

definir "ExpectedValue=4.4.9"

1. Abrir: Gerenciamento de Política de Grupo (gpmc.msc)
2. Clique com o botão direito do mouse na UO desejada
3. Selecione: Crie um GPO neste domínio e vincule-o aqui
4. Nomeie: Implantar o Almaden Agent

1. Na máquina de destino, execute: gpupdate /force
2. Reinicie a máquina (o script de inicialização é executado na inicialização)
3. Verificar a instalação:
   • Verificar os programas instalados
   • Check registry key: HKLM\…\Uninstall\{GUID}

• Verifica se o agent já agent instalado
• Lê a versão instalada no Registro do Windows
• Compara com a versão esperada
• Se forem diferentes ou estiverem faltando → instale
• Se for igual → ignora a instalação

Isso evita reinstalações desnecessárias e garante o controle de versões em todo o ambiente.

• Utilize parâmetros silenciosos no instalador, quando disponíveis
• Mantenha o instalador em um compartilhamento de rede de alta disponibilidade
• Controle de versão do pacote e do script
• Teste em uma unidade organizacional controlada antes da implantação total
• Monitorar os resultados da instalação por meio dos logs (se implementado)

Após aplicar esta configuração:

• Os agentes são instalados automaticamente na inicialização do sistema
• Não é necessária nenhuma interação do usuário
• A implantação é centralizada e escalável
• A consistência da versão é mantida em todos os dispositivos